// orbiting creatures
// wander till someone appears.

int screenX = 600;
int screenY = 600;
int howMany = 80;
int targetSize = 40;
float Gx = 20.5;
float Gy = 20.5;
float Kx = 0.1;
float Ky = 0.1;
float orbitDistance = 80;

HashSet bichos  = new HashSet();
HashSet targets = new HashSet();
HashSet moving  = new HashSet();
Target nulltarget;

void setup() {
  nulltarget = new Target(0,0);  

  for (int i=0; i<howMany; i++) {
    bichos.add(new Bicho());
  }

  size(600, 600);
  framerate(25);
  background(255);
  smooth();
}

void draw() {
  background(255);
  Iterator it = bichos.iterator();
  while (it.hasNext()){
    Bicho bicho = (Bicho)it.next();
    bicho.step();
    bicho.draw();
  }

  it = targets.iterator();
  while (it.hasNext()){
    Target target = (Target)it.next();
    if (target.deleted) {
      it.remove();
    }
    else {
      target.draw();
    }
  }

}

void mouseDragged() {
  Iterator it = moving.iterator();
  while (it.hasNext()){
    Target target = (Target)it.next();
    target.x = mouseX-screenX/2;
    target.y = mouseY-screenY/2;
  }
}

void mousePressed() {
  if (mouseButton == LEFT) { 
    // check if we are moving an existing one.
    moving.clear();
    Iterator it = targets.iterator();
    while (it.hasNext()){
      Target target = (Target)it.next();
      float d = dist(mouseX-screenX/2, mouseY-screenY/2, target.x, target.y);
      if (d < targetSize/2) {
        moving.add(target);
      }
    }
    if (moving.size() == 0) {
      // none near, create a new one
      Target t = new Target(mouseX-screenX/2, mouseY-screenY/2);
      targets.add(t);
    }
  }
  else if (mouseButton == RIGHT) {
    // delete the nearest target
    Iterator it = targets.iterator();
    while (it.hasNext()) {
      Target target = (Target)it.next();
      float d = dist(mouseX-screenX/2, mouseY-screenY/2, target.x, target.y);
      if (d < targetSize) {
        target.deleted = true;
      }
    }
  }
}

void keyPressed() {
  if (keyCode == DELETE) {
    // space: delete all targets
    targets.clear();
  }
} 


// ------------------------------------
// ------------------------------------
// ------------------------------------
// ------------------------------------
// ------------------------------------
// --- class bicho --------------------
class Bicho {

  float diameter = 5;
  Target target = null;
  int  clockwise = 1;
  color fillColor;

  float lastTime = 0;
  float m = 1.2;
  float x;
  float y; 
  float vx = 0;
  float vy = 0;
  float ax = 0;
  float ay = 0;

  Bicho() {
    this(random(-screenX/2,screenX/2), random(-screenY/2,screenY/2)); 
  }

  Bicho(float posX, float posY) {
    this.x = posX;
    this.y = posY;
    m = random(5.1,100.6);
    diameter = diameter * m / 10;
    target = new Target(0,0);
    lastTime = millis();
    clockwise = (random(-1,1)>0?1:-1);
    fillColor = color(random(150,250),random(150,250),(m*97)%255);

  }


  void step() {

    // choose the nearest target. 
    if (targets.size() == 0) {
      target = nulltarget;
    } 
    else {
      float minDist = 99999999;
      Iterator it = targets.iterator();
      while (it.hasNext()) {
        Target t = (Target)it.next();
        float d = dist(x,y, t.x, t.y);
        if (d < minDist) {
          minDist = d;
          target = t;
        }
      }
    }

    float dt = millis() - lastTime;
    lastTime = millis();

    float d = dist(x,y,target.x,target.y);
    float dx = target.x - x;
    float dy = target.y - y;

    // si estan muy cerca, no los toco
    if (d > 10) {
      // dx/d = cos,  dy/d = sin
      ax = (dx/d) * Gx * target.m / (d*d);
      ay = (dy/d) * Gy * target.m / (d*d);
      ax = ax + ( (dx/d) * Kx * sqrt(d) / m );
      ay = ay + ( (dy/d) * Ky * sqrt(d) / m );

      ax = ax / 100;
      ay = ay / 100;
    } 
    vx = vx + ax * dt;
    vy = vy + ay * dt;    
    x = x + vx*dt;
    y = y + vy*dt;

    // los roto un poquito
    // esto seria bueno que se hiciera de acuerdo al angulo de aproximacion (izq o der)
    float r = clockwise * (-HALF_PI)/153;
    x = ( x*cos(r) - y*sin(r) );
    y = ( x*sin(r) + y*cos(r) );    

    // siempre tiro un poco hacia el centro
    x = x * 0.99;
    y = y * 0.99;

  }

  void draw() {
    // screen coords
    float sx = x + screenX/2;
    float sy = y + screenY/2;

    noStroke();
    fill(fillColor);
    ellipse(sx,sy,diameter,diameter);
  }
}


// ------------------------------------
// ------------------------------------
// ------------------------------------
// ------------------------------------
// ------------------------------------
// --- class Target -------------------
class Target {
  float x = 0;
  float y = 0;
  float m = 1;
  boolean deleted = false;

  Target(float posX, float posY) {
    this.x = posX;
    this.y = posY;
  }

  void draw() {
    // screen coords
    float tsx = x + screenX/2;
    float tsy = y + screenY/2;

    stroke(200);
    noFill();
    ellipse(tsx,tsy,targetSize,targetSize);
  }

}